CodeH's World: 직구한 LG TV 로컬변경 PC없이 자동으로 하기.

예전에 직구한 LG TV 로컬변경을 이전 블로그에서 포스팅 한적이 있습니다. (이전 블로그 글 링크)
지인이 이번에 또 LG TV를 직구 했는데 로컬 변경을 물어 보는데... 문제는 컴맹입니다...
그래서 컴맹도 쉽게 로컬 변경을 할수 있게 Arduino 를 사용해서 만들어 봤습니다.
서비스 단자에 이어폰 짹을 꼽고 USB 를 꼽아서 전원을 넣어주면 로컬 변경이 됩니다.
구지 사이즈가 클 필요가 없어서 Arduino Pro Mini에 Max3232 칩을 사용 했습니다.
USB 전원을 연결하면 비쥬얼 적인 효과를 위해서 LED가 깜빡이고 로컬 변경 코멘드를 전송 합니다.

그냥 단순하게 한가지 동작만 한다면 점퍼를 쓸필요가 없어서 저항 쓸 필요도 없이 아주 간단한 구성이 될텐데 괜히 범용성 생각하다가 보드가 지저분해 졌네요~

보드 뒷면인데 따로 회로 구성을 할 필요도 없이 간단 하지만 그래도 또 TV 제작 년도 별로 커멘드가 다르고, 다시 US 로컬 변경을 할 필요가 있어서 년도 선택 3개 한국,미국 선택 2개 해서..점퍼를 5개 구성해 줬습니다.

Arduino 소스 코드는 아래와 같습니다.
처음 부팅시 점퍼를 검사해서 년도모드 1~3을 검색하고 점퍼가 안 꼽혀 있으면 모드 3 입니다.
그리고 로컬 모드 KR,US를 검사해서 설정 합니다..점퍼가 안꼽혀 있으면 모드 0으로 KR로 로컬 변경을 한후 약 10초후 다시 US로 로컬 변경을 합니다. 즉 처음 보드에 전원을 넣고 KR 로 로컬 변경을 한후 보드를 빼면 KR 로컬이고... 10초 더 기다렸다가 US 로컬 변경까지 한후 보드를 빼면 US 로컬 변경이 되겠습니다.

#include <SoftwareSerial.h>

const int PinModeYear1 =  9;
const int PinModeYear2 =  8;
const int PinModeYear3 =  7;
const int PinModeKR =  2;
const int PinModeUS =  3;

String strSetName , strSetKR, strSetUS, strSetAdd;
int nModeYear = 3;
int nModeLocal = 0;

SoftwareSerial mySerial(10, 11); // RX, TX
void setup() {
  
  pinMode(LED_BUILTIN, OUTPUT);
  pinMode (PinModeYear1, INPUT);
  pinMode (PinModeYear2, INPUT);
  pinMode (PinModeYear3, INPUT);
  pinMode (PinModeKR, INPUT);
  pinMode (PinModeUS, INPUT);

  mySerial.begin(9600);
  Serial.begin(9600);


  if (digitalRead(PinModeYear1) == HIGH) nModeYear = 1;
  if (digitalRead(PinModeYear2) == HIGH) nModeYear = 2;
  if (digitalRead(PinModeYear3) == HIGH) nModeYear = 3;
  
  if (digitalRead(PinModeKR) == HIGH) nModeLocal = 1;
  if (digitalRead(PinModeUS) == HIGH) nModeLocal = 2;

  if (nModeYear == 1) { 
    //2014년 LB5900~6000
    //2015년 55LF6000
    strSetName = "2014~2015";
    strSetKR = "AN 00 01 4B 4F 52";
    strSetUS = "AN 00 02 55 53 41";
    strSetAdd = "AF 00 81 E0";
  }
  
  if (nModeYear == 2) {
    //2015년 65UF9500 ,65UF8500 
    //한국코드 - 18077
    strSetName = "2015~";
    strSetKR = "AU 00 46 9D 01 4B 4F 52";
    strSetUS = "AU 00 57 0A 02 55 53 41";
  }
  
  if (nModeYear == 3) {
    //2016년 이후
    //한국코드 - 18048  
    strSetName = "2016~";
    strSetKR = "AU 00 46 80 01 4B 4F 52";
    strSetUS = "AU 00 57 0A 02 55 53 41";
  }

  delay(500);
  Serial.println("===========================");
  Serial.println("LG TV Local Changer   v1.0");
  Serial.println("");
  Serial.println("2017/07/27");
  Serial.println("By CodeH (haesup@gmail.com)");
  Serial.println("===========================");
  Serial.println("JP9 : Year 2014   JP2 : KR");
  Serial.println("JP8 : Year 2015   JP3 : US");
  Serial.println("JP7 : Year 2016");
  Serial.println("---------------------------");
  if (nModeYear == 1) Serial.println("2014 TV");
  if (nModeYear == 2) Serial.println("2015 TV");
  if (nModeYear == 3) Serial.println("2016 TV");
  if (nModeLocal == 0) Serial.println("Local to KR.... After 10Sec... Local to US....");
  if (nModeLocal == 1) Serial.println("Local to KR....");
  if (nModeLocal == 2) Serial.println("Local to US....");
  Serial.println("");
  delay(500);
}

void loop() {

  if (nModeLocal == 1 || nModeLocal == 0) {
    digitalWrite(LED_BUILTIN, HIGH);
    delay(1000);
    digitalWrite(LED_BUILTIN, LOW);    
    delay(2000);
    Blink_CountDown(30);
    Serial.print("Set Local to Kor : ");
    Serial.println(strSetName);  
    Serial.print("Command : ");
    Serial.println(strSetKR);  
    mySerial.println(strSetKR);
    delay(2000);
    digitalWrite(LED_BUILTIN, HIGH);
    delay(1000);
    digitalWrite(LED_BUILTIN, LOW);   
    delay(500); 
    
    delay(5000);
  }
  
  
  
  if (nModeLocal == 2 || nModeLocal == 0) {
    digitalWrite(LED_BUILTIN, HIGH);
    delay(1000);
    digitalWrite(LED_BUILTIN, LOW);    
    delay(500);
    digitalWrite(LED_BUILTIN, HIGH);
    delay(1000);
    digitalWrite(LED_BUILTIN, LOW);    
    delay(2000);
    Blink_CountDown(40);
    Serial.print("Set Local to US : ");
    Serial.println(strSetName);  
    Serial.print("Command : ");
    Serial.println(strSetUS);  
    mySerial.println(strSetUS);
    delay(2000);
    digitalWrite(LED_BUILTIN, HIGH);
    delay(1000);
    digitalWrite(LED_BUILTIN, LOW);    
    delay(500);
    digitalWrite(LED_BUILTIN, HIGH);
    delay(1000);
    digitalWrite(LED_BUILTIN, LOW);    
    delay(500);
    
    delay(5000);
  }
  
  Serial.println("Work Finish!!!!!");
  while (1) delay (100);
}

void Blink_CountDown(int in) 
{
  int i;  
  for (int j = in ; j >= 0 ; --j) {
    i = j;
    if (i < 5) i = 5;
    if (i > 30) i = 30;
    digitalWrite(LED_BUILTIN, HIGH);
    delay(i * 10);
    digitalWrite(LED_BUILTIN, LOW);
    delay(i * 10);    
    Serial.print(".");
  }
  Serial.println("");
}

PC에 연결해서 점퍼 연결에 따라 커맨드가 정상적으로 전송 되는것을 확인 했고 이제 TV에 바로 연결 할수 있도록 이어폰 짹으로 변경 했습니다.
서비스 단자에 RX,TX가 항상 헷갈려서.... RX,TX 바꺼서 꼽을수 있게 짹 타입으로 하다보니 좀 지저분 하네요....확인해 보고 잘되는 핀 찾아서 그냥 납땜해 버려야 겠습니다.

서비스 단자에 4.5파이 이어폰 케이블 꼽고 USB 전원 넣고... 끝...
LED가 비쥬얼 적인 효과로 깜빡이긴 하는게...좀 기다려야 하네요...
그거 시름 그냥 딜레이 빼면 5초안에 가능 하겠군요~
[video width="720" height="404" mp4="http://codeh.kr/wp-content/uploads/2017/07/KakaoTalk_Video_20170728_1529_19_013.mp4"][/video]
설정 - 일반에서 국가 선택에 미국 밖에 없는데...

로컬 변경을 하면...이렇게 한국을 선택 할수 있습니다.

채널 검색에서도 한국 방송 잘~ 잡힙니다~

사실 서비스포트 프로토콜만 안다면...
따로 점퍼 스위치 안쓰고.... 보드에서 TV로 쿼리 날리고 답변온 티비 모델명을 가지고
거기에 맞는 커멘드를 날려주면 완전 자동으로 가능 하겠지만...자료를 구할데가 없으니 그냥 단방향으로 커멘드만 날리는 것만 가능 하겠군요..

그리고 새로운 커맨드가 있다면 커맨드 공유 해 주시면 소스 코드에 반영 하겠습니다~

CodeH's World

2019년 4월 22일 월요일

직구한 LG TV 로컬변경 PC없이 자동으로 하기.

댓글 1개:

카테고리